kfujitoの徒然（ｂｙ浮沈子）

Ｍ値再登場！


（潜降）
http://kfujito2.asablo.jp/blog/2015/09/13/7790890

（滞底）
http://kfujito2.asablo.jp/blog/2015/09/13/7791360

今回は、Ｍ値を取り込むところだけ。

「10 rem cls
20 rem
30 rem ＜＜＜＜潜降＞＞＞＞
40 rem
50 pa = 100
60 pb = 0
70 nn2 = 0.79
80 r = 10 : rem input "潜行速度(m/分) ? ",r
90 r = 10*r
100 m = 40 : rem input "作業深度(m) ? ",m
110 t = 10*m/r
120 qn2 = 74.5207
130 e = exp(1)
140 dim harf_time(16)
150 dim k(16)
160 dim bunatu(16)
170 for i = 1 to 16
180 read harf_time(i)
190 k(i) = log(2)/harf_time(i)
200 bunatu(i) = (pa+pb)*nn2+r*nn2*(t-1/k(i))-((pa+pb)*nn2-qn2-r*nn2/k(i))*e^(-k(i)*t)
210 next i
220 data 5,8,12.5,18.5,27,38.3,54.3,77,109,146,187,239,305,390,498,635
230 rem
240 rem ＜＜＜＜作業＞＞＞＞
250 rem
260 pb = 10*m
270 dim qn2(16)
280 r = 0
290 t = 60 : rem input "作業時間(分) ? ",t
300 for i = 1 to 16
310 qn2(i) = bunatu(i)
320 bunatu(i) = (pa+pb)*nn2+r*nn2*(t-1/k(i))-((pa+pb)*nn2-qn2(i)-r*nn2/k(i))*e^(-k(i)*t)
330 next i
340 rem
350 rem ＜＜＜＜Ｍ値＞＞＞＞
360 rem
370 dim mvn2a(16)
380 for i = 1 to 16
390 read mvn2a(i)
400 next i
410 data 126.885,109.185,94.381,82.446,73.918,63.153,56.483,51.133,48.246,43.709,40.774,38.68,34.463,33.161,30.765,29.284
420 dim mvn2b(16)
430 for i = 1 to 16
440 read mvn2b(i)
450 next i
460 data 0.5578,0.6514,0.7222,0.7825,0.8126,0.8434,0.8693,0.891,0.9092,0.9222,0.9319,0.9403,0.9477,0.9544,0.9602,0.9653
470 for i = 1 to 16
480 print i,mvn2a(i),mvn2b(i)
490 next i
500 end」

クリアスクリーン（１０行目）、インプット文によるデータ入力（８０、１００、２９０行目）をコメントアウトして規定値を直書きしていたり、内容ごとに見出しを付けたり（３０、２４０、３５０行目辺り）、少し手を入れているが、基本は同じだ。

Ｍ値（の係数）については、例のページからコピペする。

（改正高気圧作業安全衛生規則が施行されます： 高気圧作業安全衛生規則第八条第二項等の規定に基づく厚生労働大臣が定める方法等（平成26年12月１日厚生労働省告示第457号）参照）
http://www.mhlw.go.jp/stf/seisakunitsuite/bunya/0000071152.html

神の告示である。

（神の告示）
http://kfujito2.asablo.jp/blog/2015/08/26/7750625

まあいい。

こっちは、それどころじゃない。

それを、配列（mvn2a(16)、mvn2b(16)）に取り込んでいる。

実行するとこんな感じ。

「>run
1 126.885 0.5578
2 109.185 0.6514
3 94.381 0.7222
4 82.446 0.7825
5 73.918 0.8126
6 63.153 0.8434
7 56.483 0.8693
8 51.133 0.891
9 48.246 0.9092
10 43.709 0.9222
11 40.774 0.9319
12 38.68 0.9403
13 34.463 0.9477
14 33.161 0.9544
15 30.765 0.9602
16 29.284 0.9653
>」

第一と第二半飽和組織のところが、画面ではうまくプリントできないんだが、細かいことは気にしない。

もう、配列のハンドリングは慣れたものだ。

どうやら、read文とdata文は、出てきた順番に対応するようで、心配していたバッティングとかはない。

さすがに、その辺りは言語環境を作る時に配慮しているようだ。

Ｍ値の係数とかは、どこで取り込んでもいいので、本来ならデータを読み込むディビジョン作って、纏めて書いておくのが筋だろう（コボルかよ？）。

これに、深度のデータを入れれば、Ｍ値が求まる。

ちなみに、窒素だけだとこうなる。

M=((Pa+Pc)/mvn2b)-mvn2a

海中で水深１５ｍの半飽和時間５分のコンパートメントのＭ値は、上式によりこうなる。

((100+150)/0.5578)-126.885=321.3043151667264

この数字を、やれ水深だとか、圧力だとか（圧力ですが）といって、実際のダイビングの際の目安としようとしても、おそらく何の意味もない。

減圧モデルにおける、計算途中のただの数字だ。

どのコンパートメントを重視するかは、ダイビングのプロファイルが関係してくるし、そもそも、Ｍ値の係数がさじ加減によるものなので、当てにはならない。

しかし、この係数は臨床的に裏付けがあるので、まるっきりのデタラメではない。

というよりも、この係数こそが減圧表の命なのだ。

神の数字だな。

どっかの出版社が掲出していたホームページ上の数字が間違ってたことがあったが、浮沈子の指摘で差し替えられたりもした。

ったく、もう・・・。

まあ、どうでもいいんですが。

さすがに、この数字については、パブリックコメントでも疑義が寄せられていたが、厚労省は実績に基づくとして譲らなかった。

（「高気圧作業安全衛生規則の一部を改正する省令及び高気圧作業安全衛生規則第八条第二項等の規定に基づく厚生労働大臣が定める方法等に係る異見募集について」に対して寄せられた御意見等について：「異見募集」って、何なんだあ？）
http://search.e-gov.go.jp/servlet/Public?CLASSNAME=PCMMSTDETAIL&id=495130288&Mode=2

「Ｑ：減圧表の計算の根拠について、a 値や安全率をどのようにして導いているのか。」

「Ａ：今般新たに規定した減圧管理方法は検討会報告書を踏まえたものです。具体的な導出方法については検討会報告書第３（２）や参考文献である厚生労働科学研究「新しい標準減圧表作成に伴う実地調査および検証調査研究」の報告書第４章から第５章、その他専門図書で御確認ください。」

間違いないから、安心しろと言われてもなあ・・・。

とにかく、係数の取り込みは成功した。

当該深度が分かれば、１６のコンパートメント全てのＭ値のセットを出せる。

その深度の窒素分圧は、コンパートメント毎に算出可能である。

あとは、海面からの深度を３ｍ刻みにして、分圧とＭ値を突合して、判定ロジックを書いて実装するだけだ。

そこの所がキモなのは分かっている。

だけど、今日は限界だな。

明日は、インスピの点検とか、石垣ダイビングの準備で忙しいしな。

帰って来てからやることになるだろう。

外堀は埋まってきた。

石垣を登れば、天守閣はすぐそこである。

うん？、石垣繋がりかあ？。

まあ、そういうことにしておこうか・・・。